一个电压反馈放大器宏模型可以仿真共同效果，如瞬态响应、频率响应、电压噪声和输入/输出压摆率(slew rate)限制。接下来我们将以实例模型详尽描述每个级和相关实际器件的行为。这里没有提供完整的晶体管原理图，客户可以利用充分提取的3D器件模型进行精确的仿真来开发宏模型。

　　第一个关于运算放大器宏 模型的技术是由Boyle在1974年开发的，仅使用了两个晶体管、几个二极管和线性元件。[1]电阻、电容、电感器和电压/电流控制源等线性元件的仿真 远远快于有源元件(active element)，并可用来提供极点、零点和任意增益。采用DC模型，可以用一个电压控制电压源作放大器，同时可以增加电阻以更好地表示输入和输出阻抗。电容、电感、二极管和晶体管可以提供适当的交流响应。欲了解更多关于仿真模型的开发信息，请参见参考文献Alexander和Bowers[2]和[3]。他们的模型如本例后面所述。

　　ISL28133是一个采用电压反馈拓扑结构的零漂移运算放大器。其增益带宽积为400kHz，压摆率为0.2V/微秒，电源电流为18μA。图1显示了一个五级模型，它代表了实际电路框图。这些级包括输入、增益、频率整形、输出和噪声模块。

　　图1. ISL28133宏模型框图

　　(图字：输入级，增益级，频率整形级，输出级，噪声模块)

　　输入级

　　零漂移放大器的 输入级如图2所示。100μA的电流源“I2”馈送pmos输入对。一般情况下，I2应选择低于静态电流。请记住，ISL28133的典型电源电流 (RL=open)仅为18μA。然而，很小的I2(约10μA)将使输入电压噪声过大而无法仿真。这将在后面的噪声分析部分讨论。选择 I2=100μA，并使用I1进行补偿。Cin1和Cin2是输入共模电容，Cdiff是差模输入电容。

　　图2. 输入级

　　增益级

　　这一级可以执行模型中的一些重要功能

　　1)本级设置该部分的DC增益。所有后续级均可提供增益。

　　2)可实现压摆率限制。

　　3)在AC特性中增加主极点(dominant pole)。

　　4)将信号从以电源作为参考量的两个电压水平移位至一个以中点作为参考量的单电压。

　　5)限制输出。

　　参见图3，Ga是电路(block)G1和G2的增益。Gb是电路G3和G4的增益。

改变V3和V4的值可以限制压摆率。此外，R8/C1和R7/C2决定了这一模式的主极点。E1用来在Vcc和Vee的中间设置参考电平。

　　图3. 增益级

　　频率整形级

　　这里采用的“伸缩”频率整形技术是常见的运算放大器建模方法。它很容易增加更多的极点和零点。每个频率整形电路可以提供增益。这个模型包含的零极对如图4所示。

　　高阶极点级G7/8、R13/14和C3/4如图5所示。

　　图4. 零极点对儿级

　　图5. 高阶极点级

　　噪声仿真

　　ISL28133的输入电流噪声非常小(约70)，所以在这个模型中可以忽略不计。MOSFET的电压噪声可以用以下公式仿真：

ID是漏电流。高偏置电流需要低电压噪声。 在输入级，尾电流设置得足够高，以产生可以忽略的输入电压噪声。在增加噪声源之前，该模型将提供低于数据表中的规格或典型性能噪声曲线的噪声。图6的噪声 电压模块可通过使用一个偏置二极管-电阻器串联组合的0.1V电压源生成1/f和白噪声。白噪声是由热噪声电流产生的。

　　因此，给定噪声电压谱密度的所需电阻值为

　　该斩波稳定放大器设计可大大减少1/f噪声。1/f噪声(闪烁噪声，flicker noise)指的是出现的与频率成反比的功率谱密度噪声。更为普遍的是，具有谱密度()的噪声也称为1/f噪声。通常情况下，其中的穿越白噪声曲线的频率闪烁噪声曲线被定义为拐角频率(corner frequency)。少量的闪烁噪声仍然可在SPICE二极管模型内进行建模，参见图6。

　　图6. 噪声电压模块

　　输出级

　　在频率整形级之后，信号出现在节点VV5，它以两个电源轨的中点作为参考量。每个受控源可以产生足够的电流，以支持其并联电阻两端所需的电压 降。R15和R16等于开环输出电阻的两倍，所以它们的并联组合可提供正确的Zout。D5-D8和G9/10被用来迫使电流从正电压轨 (positive rail)流向负电压轨(negative rail)，以纠正实际电流流入或流出。

图7. 输出级

　　仿真结果

　　以下列出了某些SPICE仿真结果与来自手册的典型性能曲线的比较(见右边来自手册的图)。

图8. 增益、频率与CL的对比

　　(图字：标准增益(dB)，频率(Hz))

　　图8是增益、频率与负载电容的对比。它不是很准确，因为电路板上的寄生电容没有列在模型中。其误差小于5%。

图9. 频率响应与闭环增益对比

　　(图字：增益(dB)，频率(Hz))

　　图9是具有不同增益的闭环增益频率响应。在增益=100时，带宽为3.94kHz，误差小于5%。在低增益条件下，由于零极点对的缘故带宽扩大。

　图10. 大信号阶跃响应(4V)

　　(图字：大信号(V)，时间(μs))

　　图10是大信号阶跃响应。仿真的压摆率为0.198V/μs，误差为1%。

结论

　　电压反馈放大器全 面的SPICE宏模型包括诸如传输响应(transfer response)、准确的AC响应，DC偏移和电压噪声的影响。它很容易增加更多的功能，如共模抑制比(CMRR)、电源抑制比(PSRR)、输入电流 噪声等等。此外，它还可以方便地改变模型的参数，以适应其他的电压反馈放大器。几款Intersil的电压反馈放大器采用了相同的模式拓扑结构。

　　ISL28133宏模型网表

　　* ISL28133宏模型

　　* B版本，2009年7月

　　* 该模型可仿真AC特性、电压噪声、瞬态响应

　　* 连接： +输入

　　* | -输入

　　* | | +电源电压

　　* | | | -电源电压

　　* | | | | 输出

　　* | | | | |

　　.subckt ISL28133 3 2 7 4 6

　　*Input Stage

　　C_Cin1 8 0 1.12p

　　C_Cin2 2 0 1.12p

　　C_Cd 8 2 1.6p

　　R_R1 9 10 10

　　R_R2 10 11 10

　　R_R3 4 12 100

　　R_R4 4 13 100

　　M_M1 12 8 9 9 pmosisil

　　+ L=50u

　　+ W=50u

　　M_M2 13 2 11 11 pmosisil

　　+ L=50u

　　+ W=50u

　　I_I1 4 7 DC 92uA

　　I_I2 7 10 DC 100uA

　　*Gain stage

　　G_G1 4 VV2 13 12 0.0002

　　G_G2 7 VV2 13 12 0.0002

　　R_R5 4 VV2 1.3Meg

　　R_R6 VV2 7 1.3Meg

　　D_D1 4 14 DX

　　D_D2 15 7 DX

　　V_V3 VV2 14 0.7Vdc

　　V_V4 15 VV2 0.7Vdc

　　*SR limit first pole

　　G_G3 4 VV3 VV2 16 1

　　G_G4 7 VV3 VV2 16 1

　　R_R7 4 VV3 1meg

　　R_R8 VV3 7 1meg

　　C_C1 VV3 7 12u

　　C_C2 4 VV3 12u

　　D_D3 4 17 DX

　　D_D4 18 7 DX

　　V_V5 VV3 17 0.7Vdc

　　V_V6 18 VV3 0.7Vdc

　　*Zero/Pole

　　E_E1 16 4 7 4 0.5

　　G_G5 4 VV4 VV3 16 0.000001

　　G_G6 7 VV4 VV3 16 0.000001

　　L_L1 20 7 0.3H

　　R_R12 20 7 2.5meg

　　R_R11 VV4 20 1meg

　　L_L2 4 19 0.3H

　　R_R9 4 19 2.5meg

　　R_R10 19 VV4 1meg

　　*Pole

G_G7 4 VV5 VV4 16 0.000001

　　G_G8 7 VV5 VV4 16 0.000001

　　C_C3 VV5 7 0.12p

　　C_C4 4 VV5 0.12p

　　R_R13 4 VV5 1meg

　　R_R14 VV5 7 1meg

　　*Output Stage

　　G_G9 21 4 6 VV5 0.0000125

　　G_G10 22 4 VV5 6 0.0000125

　　D_D5 4 21 DY

　　D_D6 4 22 DY

　　D_D7 7 21 DX

　　D_D8 7 22 DX

　　R_R15 4 6 8k

　　R_R16 6 7 8k

　　G_G11 6 4 VV5 4 -0.000125

　　G_G12 7 6 7 VV5 -0.000125

　　*Voltage Noise

　　D_DN1 102 101 DN

　　D_DN2 104 103 DN

　　R_R21 0 101 120k

　　R_R22 0 103 120k

　　E_EN 8 3 101 103 1

　　V_V15 102 0 0.1Vdc

　　V_V16 104 0 0.1Vdc

　　.model pmosisil pmos (kp=16e-3 vto=10m)

　　.model DN D(KF=6.4E-16 AF=1)

　　.MODEL DX D(IS=1E-18 Rs=1)

　　.MODEL DY D(IS=1E-15 BV=50 Rs=1)

　　.ends ISL28133

　参考文献

　　1. BOYLE，G.R.，“集成电路运算放大器的宏建模”，IEEE J. 1974, SC-9。

　　2. Derek Bowers、Mark Alexander、Joe Buxton，“‘电流反馈’运算放大器的综合仿真宏模型”，IEEE学报，137卷，1990年4月，137-145页。

　　3. Mark Alexander、Derek Bowers，“符合AN-138 SPICE的运算放大器宏模型”，ADI公司，应用笔记138。

　　4. “用于‘电流反馈’放大器的全面SPICE宏模型AN-840的开发”，美国国家开云棋牌官网在线客服公司，应用笔记840。